Add temporary dev-scheme/chibi

dev-scheme/chibi/chibi-9999.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+REAL_PN="${PN}-scheme"
+REAL_PV="$(ver_cut 1-2)"
+REAL_P="${REAL_PN}-${REAL_PV}"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Minimal Scheme implementation for use as an extension language"
+HOMEPAGE="http://synthcode.com/scheme/chibi/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/ashinn/${REAL_PN}.git"
+else
+	SRC_URI="https://github.com/ashinn/${REAL_PN}/archive/${REAL_PV}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${REAL_P}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+src_configure() {
+	tc-export CC
+
+	# upstream uses $(FEATURES) in makefile, which collides with the portage variable
+	sed -i 's/FEATURES/z&/g' Makefile || die
+
+	export PREFIX="${EPREFIX}/usr"
+	export LIBDIR="${EPREFIX}/usr/$(get_libdir)"
+	export SOLIBDIR="${EPREFIX}/usr/$(get_libdir)"
+
+	# If "ldconfig" exists it is ran, overwrite it with "LDCONFIG" variable.
+	export LDCONFIG="0"
+}
+
+src_install() {
+	default
+
+	dosym "${REAL_PN}" "/usr/bin/${PN}"
+}

metadata/md5-cache/dev-scheme/chibi-9999

@@ -0,0 +1,11 @@
+BDEPEND=>=dev-vcs/git-1.8.2.1[curl]
+DEFINED_PHASES=configure install unpack
+DESCRIPTION=Minimal Scheme implementation for use as an extension language
+EAPI=8
+HOMEPAGE=http://synthcode.com/scheme/chibi/
+INHERIT=toolchain-funcs git-r3
+LICENSE=BSD
+PROPERTIES=live
+SLOT=0
+_eclasses_=toolchain-funcs	30214924c0c3b92ec7dbf24fc70d60d3	git-r3	875eb471682d3e1f18da124be97dcc81
+_md5_=9d4c4c4c761aa152f2d2eb19c0910166